À partir d'un tableau de code-barres et d'un tableau de cotes, ce script ajoute la cote à chaque exemplaire.

Sub AjouteCoteCodeBarre()
	Dim CodeBarre, Chaine, NouvelleChaine, CodePEB, PositionDollar_j, Num, Cote
	Num = 0
	Dim LesCodesBarres
	Dim LesCotes
	LesCodesBarres = Array("0260821810","0260821896","0260821902","0260821827","0260821834")
	LesCotes = Array("082181","082189","082190","082182","082183")
	For Each CodeBarre In LesCodesBarres
		Application.ActiveWindow.Command "che cod " & CodeBarre
		If Application.ActiveWindow.Variable("P3GSZ") > 1 Then
			InputBox "Doublons de codes-barres", "Problème", CodeBarre
		Else
			If Application.ActiveWindow.Messages.Count = 0 Then
				Application.ActiveWindow.Command "mod", False
				Dim TrouveCodeBarre
				TrouveCodeBarre = Application.ActiveWindow.Title.Find(CodeBarre, True, False, False)
				If TrouveCodeBarre = True Then
					Application.ActiveWindow.Title.LineDown()
					Application.ActiveWindow.Title.StartOfField()
					If Application.ActiveWindow.Title.tag = "930" Then
						Chaine = Application.ActiveWindow.Title.currentField
						If InStr(Chaine, "$a") <> 0 Then
							InputBox "Problème", "Problème", "Cote deja presente : " & CodeBarre & ":" & Application.ActiveWindow.Variable("P3GPP")
						Else
							PositionDollar_j = InStr(Chaine, "$j")
							If PositionDollar_j = 0 Then
								Cote = "$a" & LesCotes(Num)
								NouvelleChaine = Chaine & Cote
							Else
								CodePEB = Mid(Chaine, PositionDollar_j)
								Cote = "$a" & LesCotes(Num) & CodePEB
								NouvelleChaine = Replace(Chaine, CodePEB, Cote)
							End If	
							Application.ActiveWindow.Title.InsertText(NouvelleChaine)
							Application.ActiveWindow.Title.deleteToEndOfLine
							Application.activeWindow.simulateIBWKey "FR"					
						End If
					End If
				End If
			Else
				InputBox "Problème", "Problème", Application.ActiveWindow.Messages.item(0) & ":" & CodeBarre & ":" & Application.ActiveWindow.Variable("P3GPP")
			End If
		End If
		Num = Num + 1
	Next
End Sub

Noter au début comment on trouve les doublons de codes-barres, simplement en regardant le nombre de notices dans le lot.