Formules conditionnelles

SOMME.SI

Renvoie la somme des valeurs répondant à une condition.

Syntaxe : =SOMME.SI(<plage_condition>;<condition>;[<plage_addition>])
<plage_condition> : la plage sur laquelle porte la condition qui suit : est-ce que les valeurs de cette plage répondent à la condition ?
<condition> : renvoie VRAI ou FAUX. Voir exemples ci-dessous.
<plage_addition> : la plage dont j'additionne les valeurs des cellules répondant à <condition>
Si <plage_addition> n'est pas précisée, ce sont les valeurs de <plage_condition> qui sont ajoutées.

Exemples :
=SOMME.SI(A:A;">5";B:B) : additionne les valeurs de la colonne B si les valeurs de la colonne A sont supérieures à 5.
=SOMME.SI(C2:C91;"ECONOMIE ETRANGERS*";B2:B91) : additionne les valeurs de la plage B2:B91 à condition que les cellules C2:C91 contiennent un texte commençant par "ECONOMIE ETRANGERS".

SI

Renvoie une valeur en fonction d'une condition.

Syntaxe : =SI(<condition>;<valeur si vrai>;<valeur si faux>)
<valeur si vrai> : la valeur renvoyée par la formule et affichée dans la cellule où se trouve la formule. Si on ne précise pas de valeur à renvoyer, la formule affiche les chaînes "VRAI" ou "FAUX".

Exemples :
=SI(B16=142;1;0) : Si la cellule B16 comporte la valeur 142, afficher 1, sinon afficher 0.
=SI(OU(EXACT(GAUCHE('Liste gén abnt 2010 éco-gestion'!F5;8);"ECONOMIE");EXACT(GAUCHE('Liste gén abnt 2010 éco-gestion'!F5;7);"GESTION"));'Liste gén abnt 2010 éco-gestion'!A5)

=SI
(
 OU
 	(
	 EXACT
		(
		GAUCHE('Liste gén abnt 2010 éco-gestion'!F5;8)
		;
		"ECONOMIE"
		)
	;
	EXACT
		(
		GAUCHE('Liste gén abnt 2010 éco-gestion'!F5;7)
		;
		"GESTION"
		)
	)
;
'Liste gén abnt 2010 éco-gestion'!A5
)

Si La cellule F5 de la feuille 'Liste gén abnt 2010 éco-gestion' comporte un texte qui commence par "ECONOMIE" ou "GESTION", afficher la valeur de la cellule A5 de cette feuille ; sinon, la formule affiche simplement "FAUX".

NB.SI

Renvoie le nombre de cellules répondant à une condition

Syntaxe : =NB.SI(<plage_condition>;<condition>)

Exemple :
=NB.SI(B1:B10;">100") : nombre de cellules (dans la plage B1:B10) dont la valeur est strictement supérieure à 100.